MOM_CVMix_conv.F90

!> Interface to CVMix convection scheme.
module mom_cvmix_conv

! This file is part of MOM6. See LICENSE.md for the license.

use mom_debugging,      only : hchksum
use mom_diag_mediator,  only : diag_ctrl, time_type, register_diag_field
use mom_diag_mediator,  only : post_data
use mom_eos,            only : calculate_density
use mom_error_handler,  only : mom_error, is_root_pe, fatal, warning, note
use mom_file_parser,    only : openparameterblock, closeparameterblock
use mom_file_parser,    only : get_param, log_version, param_file_type
use mom_grid,           only : ocean_grid_type
use mom_unit_scaling,   only : unit_scale_type
use mom_variables,      only : thermo_var_ptrs
use mom_verticalgrid,   only : verticalgrid_type
use cvmix_convection,   only : cvmix_init_conv, cvmix_coeffs_conv
use cvmix_kpp,          only : cvmix_kpp_compute_kobl_depth

implicit none ; private

#include <MOM_memory.h>

public cvmix_conv_init, calculate_cvmix_conv, cvmix_conv_end, cvmix_conv_is_used

!> Control structure including parameters for CVMix convection.
type, public :: cvmix_conv_cs

  ! Parameters
  real    :: kd_conv_const !< diffusivity constant used in convective regime [m2 s-1]
  real    :: kv_conv_const !< viscosity constant used in convective regime [m2 s-1]
  real    :: bv_sqr_conv   !< Threshold for squared buoyancy frequency
                           !! needed to trigger Brunt-Vaisala parameterization [s-2]
  real    :: min_thickness !< Minimum thickness allowed [m]
  logical :: debug         !< If true, turn on debugging

  ! Daignostic handles and pointers
  type(diag_ctrl), pointer :: diag => null() !< Pointer to diagnostics control structure
  !>@{ Diagnostics handles
  integer :: id_n2 = -1, id_kd_conv = -1, id_kv_conv = -1
  !>@}

  ! Diagnostics arrays
  real, allocatable, dimension(:,:,:) :: n2      !< Squared Brunt-Vaisala frequency [s-2]
  real, allocatable, dimension(:,:,:) :: kd_conv !< Diffusivity added by convection [Z2 T-1 ~> m2 s-1]
  real, allocatable, dimension(:,:,:) :: kv_conv !< Viscosity added by convection [Z2 T-1 ~> m2 s-1]

end type cvmix_conv_cs

character(len=40)  :: mdl = "MOM_CVMix_conv"     !< This module's name.

contains

!> Initialized the CVMix convection mixing routine.
logical function cvmix_conv_init(Time, G, GV, US, param_file, diag, CS)

  type(time_type),         intent(in)    :: Time       !< The current time.
  type(ocean_grid_type),   intent(in)    :: G          !< Grid structure.
  type(verticalgrid_type), intent(in)    :: GV         !< Vertical grid structure.
  type(unit_scale_type),   intent(in)    :: US         !< A dimensional unit scaling type
  type(param_file_type),   intent(in)    :: param_file !< Run-time parameter file handle
  type(diag_ctrl), target, intent(inout) :: diag       !< Diagnostics control structure.
  type(cvmix_conv_cs),     pointer       :: CS         !< This module's control structure.
  ! Local variables
  real    :: prandtl_conv !< Turbulent Prandtl number used in convective instabilities.
  logical :: useEPBL      !< If True, use the ePBL boundary layer scheme.

! This include declares and sets the variable "version".
#include "version_variable.h"

  if (associated(cs)) then
    call mom_error(warning, "CVMix_conv_init called with an associated "// &
                            "control structure.")
    return
  endif
  allocate(cs)

  ! Read parameters
  call get_param(param_file, mdl, "USE_CVMix_CONVECTION", cvmix_conv_init, default=.false., do_not_log=.true.)
  call log_version(param_file, mdl, version, &
           "Parameterization of enhanced mixing due to convection via CVMix", &
           all_default=.not.cvmix_conv_init)
  call get_param(param_file, mdl, "USE_CVMix_CONVECTION", cvmix_conv_init, &
                 "If true, turns on the enhanced mixing due to convection "//&
                 "via CVMix. This scheme increases diapycnal diffs./viscs. "//&
                 "at statically unstable interfaces. Relevant parameters are "//&
                 "contained in the CVMix_CONVECTION% parameter block.", &
                 default=.false.)

  if (.not. cvmix_conv_init) return

  call get_param(param_file, mdl, "ENERGETICS_SFC_PBL", useepbl, default=.false., &
                do_not_log=.true.)

  ! Warn user if EPBL is being used, since in this case mixing due to convection will
  ! be aplied in the boundary layer
  if (useepbl) then
     call mom_error(warning, 'MOM_CVMix_conv_init: '// &
           'CVMix convection may not be properly applied when ENERGETICS_SFC_PBL = True'//&
           'as convective mixing might occur in the boundary layer.')
  endif

  call get_param(param_file, mdl, 'DEBUG', cs%debug, default=.false., do_not_log=.true.)

  call get_param(param_file, mdl, 'MIN_THICKNESS', cs%min_thickness, default=0.001, do_not_log=.true.)

  call openparameterblock(param_file,'CVMix_CONVECTION')

  call get_param(param_file, mdl, "PRANDTL_CONV", prandtl_conv, &
                 "The turbulent Prandtl number applied to convective "//&
                 "instabilities (i.e., used to convert KD_CONV into KV_CONV)", &
                 units="nondim", default=1.0)

  call get_param(param_file, mdl, 'KD_CONV', cs%kd_conv_const, &
                 "Diffusivity used in convective regime. Corresponding viscosity "//&
                 "(KV_CONV) will be set to KD_CONV * PRANDTL_TURB.", &
                 units='m2/s', default=1.00)

  call get_param(param_file, mdl, 'BV_SQR_CONV', cs%bv_sqr_conv, &
                 "Threshold for squared buoyancy frequency needed to trigger "//&
                 "Brunt-Vaisala parameterization.", &
                 units='1/s^2', default=0.0)

  call closeparameterblock(param_file)

  ! set kv_conv_const based on kd_conv_const and prandtl_conv
  cs%kv_conv_const = cs%kd_conv_const * prandtl_conv

  ! allocate arrays and set them to zero
  allocate(cs%N2(szi_(g), szj_(g), szk_(g)+1)); cs%N2(:,:,:) = 0.
  allocate(cs%kd_conv(szi_(g), szj_(g), szk_(g)+1)); cs%kd_conv(:,:,:) = 0.
  allocate(cs%kv_conv(szi_(g), szj_(g), szk_(g)+1)); cs%kv_conv(:,:,:) = 0.

  ! Register diagnostics
  cs%diag => diag
  cs%id_N2 = register_diag_field('ocean_model', 'N2_conv', diag%axesTi, time, &
      'Square of Brunt-Vaisala frequency used by MOM_CVMix_conv module', '1/s2')
  cs%id_kd_conv = register_diag_field('ocean_model', 'kd_conv', diag%axesTi, time, &
      'Additional diffusivity added by MOM_CVMix_conv module', 'm2/s', conversion=us%Z2_T_to_m2_s)
  cs%id_kv_conv = register_diag_field('ocean_model', 'kv_conv', diag%axesTi, time, &
      'Additional viscosity added by MOM_CVMix_conv module', 'm2/s', conversion=us%Z2_T_to_m2_s)

  call cvmix_init_conv(convect_diff=cs%kd_conv_const, &
                       convect_visc=cs%kv_conv_const, &
                       lbruntvaisala=.true.,    &
                       bvsqr_convect=cs%bv_sqr_conv)

end function cvmix_conv_init

!> Subroutine for calculating enhanced diffusivity/viscosity
!! due to convection via CVMix
subroutine calculate_cvmix_conv(h, tv, G, GV, US, CS, hbl)

  type(ocean_grid_type),                      intent(in)  :: G  !< Grid structure.
  type(verticalgrid_type),                    intent(in)  :: GV !< Vertical grid structure.
  type(unit_scale_type),                      intent(in)  :: US !< A dimensional unit scaling type
  real, dimension(SZI_(G),SZJ_(G),SZK_(G)),   intent(in)  :: h  !< Layer thickness [H ~> m or kg m-2].
  type(thermo_var_ptrs),                      intent(in)  :: tv !< Thermodynamics structure.
  type(cvmix_conv_cs),                        pointer     :: CS !< The control structure returned
                                                                !! by a previous call to CVMix_conv_init.
  real, dimension(SZI_(G),SZJ_(G)),           intent(in)  :: hbl !< Depth of ocean boundary layer [Z ~> m]
  ! local variables
  real, dimension(SZK_(G)) :: rho_lwr !< Adiabatic Water Density, this is a dummy
                                      !! variable since here convection is always
                                      !! computed based on Brunt Vaisala.
  real, dimension(SZK_(G)) :: rho_1d  !< water density in a column, this is also
                                      !! a dummy variable, same reason as above.
  real, dimension(SZK_(G)+1) :: kv_col !< Viscosities at interfaces in the column [m2 s-1]
  real, dimension(SZK_(G)+1) :: kd_col !< Diffusivities at interfaces in the column [m2 s-1]
  real, dimension(SZK_(G)+1) :: iFaceHeight !< Height of interfaces [m]
  real, dimension(SZK_(G))   :: cellHeight  !< Height of cell centers [m]
  integer :: kOBL                        !< level of OBL extent
  real :: g_o_rho0  ! Gravitational acceleration divided by density times unit convserion factors
                    ! [Z s-2 R-1 ~> m4 s-2 kg-1]
  real :: pref      ! Interface pressures [R L2 T-2 ~> Pa]
  real :: rhok, rhokm1 ! In situ densities of the layers above and below at the interface pressure [R ~> kg m-3]
  real :: hbl_KPP   ! The depth of the ocean boundary as used by KPP [m]
  real :: dz        ! A thickness [Z ~> m]
  real :: dh, hcorr ! Two thicknesses [m]
  integer :: i, j, k

  g_o_rho0 = us%L_to_Z**2*us%s_to_T**2 * gv%g_Earth / gv%Rho0

  ! initialize dummy variables
  rho_lwr(:) = 0.0; rho_1d(:) = 0.0

  do j = g%jsc, g%jec
    do i = g%isc, g%iec

      ! set N2 to zero at the top- and bottom-most interfaces
      cs%N2(i,j,1) = 0.
      cs%N2(i,j,g%ke+1) = 0.

      ! skip calling at land points
      !if (G%mask2dT(i,j) == 0.) cycle

      pref = 0. ; if (associated(tv%p_surf)) pref = tv%p_surf(i,j)
      ! Compute Brunt-Vaisala frequency (static stability) on interfaces
      do k=2,g%ke

        ! pRef is pressure at interface between k and km1 [R L2 T-2 ~> Pa].
        pref = pref + (gv%H_to_RZ*gv%g_Earth) * h(i,j,k)
        call calculate_density(tv%t(i,j,k), tv%s(i,j,k), pref, rhok, tv%eqn_of_state)
        call calculate_density(tv%t(i,j,k-1), tv%s(i,j,k-1), pref, rhokm1, tv%eqn_of_state)

        dz = ((0.5*(h(i,j,k-1) + h(i,j,k))+gv%H_subroundoff)*gv%H_to_Z)
        cs%N2(i,j,k) = g_o_rho0 * (rhok - rhokm1) / dz ! Can be negative

      enddo

      ifaceheight(1) = 0.0 ! BBL is all relative to the surface
      hcorr = 0.0
      ! compute heights at cell center and interfaces
      do k=1,g%ke
        dh = h(i,j,k) * gv%H_to_m ! Nominal thickness to use for increment, in the units used by CVMix.
        dh = dh + hcorr ! Take away the accumulated error (could temporarily make dh<0)
        hcorr = min( dh - cs%min_thickness, 0. ) ! If inflating then hcorr<0
        dh = max( dh, cs%min_thickness ) ! Limit increment dh>=min_thickness
        cellheight(k)    = ifaceheight(k) - 0.5 * dh
        ifaceheight(k+1) = ifaceheight(k) - dh
      enddo

      ! gets index of the level and interface above hbl
      hbl_kpp = us%Z_to_m*hbl(i,j)  ! Convert to the units used by CVMix.
      kobl = cvmix_kpp_compute_kobl_depth(ifaceheight, cellheight, hbl_kpp)

      kv_col(:) = 0.0 ; kd_col(:) = 0.0
      call cvmix_coeffs_conv(mdiff_out=kv_col(:), &
                               tdiff_out=kd_col(:), &
                               nsqr=cs%N2(i,j,:), &
                               dens=rho_1d(:), &
                               dens_lwr=rho_lwr(:), &
                               nlev=g%ke,    &
                               max_nlev=g%ke, &
                               obl_ind=kobl)

      do k=1,g%ke+1
        cs%kv_conv(i,j,k) = us%m2_s_to_Z2_T * kv_col(k)
        cs%Kd_conv(i,j,k) = us%m2_s_to_Z2_T * kd_col(k)
      enddo
      ! Do not apply mixing due to convection within the boundary layer
      do k=1,kobl
        cs%kv_conv(i,j,k) = 0.0
        cs%kd_conv(i,j,k) = 0.0
      enddo

    enddo
  enddo

  if (cs%debug) then
    call hchksum(cs%N2, "MOM_CVMix_conv: N2",g%HI,haloshift=0)
    call hchksum(cs%kd_conv, "MOM_CVMix_conv: kd_conv",g%HI,haloshift=0,scale=us%Z2_T_to_m2_s)
    call hchksum(cs%kv_conv, "MOM_CVMix_conv: kv_conv",g%HI,haloshift=0,scale=us%m2_s_to_Z2_T)
  endif

  ! send diagnostics to post_data
  if (cs%id_N2 > 0) call post_data(cs%id_N2, cs%N2, cs%diag)
  if (cs%id_kd_conv > 0) call post_data(cs%id_kd_conv, cs%kd_conv, cs%diag)
  if (cs%id_kv_conv > 0) call post_data(cs%id_kv_conv, cs%kv_conv, cs%diag)

end subroutine calculate_cvmix_conv

!> Reads the parameter "USE_CVMix_CONVECTION" and returns state.
!! This function allows other modules to know whether this parameterization will
!! be used without needing to duplicate the log entry.
logical function cvmix_conv_is_used(param_file)
  type(param_file_type), intent(in) :: param_file !< A structure to parse for run-time parameters
  call get_param(param_file, mdl, "USE_CVMix_CONVECTION", cvmix_conv_is_used, &
                 default=.false., do_not_log = .true.)

end function cvmix_conv_is_used

!> Clear pointers and dealocate memory
subroutine cvmix_conv_end(CS)
  type(cvmix_conv_cs), pointer :: CS !< Control structure for this module that
                                     !! will be deallocated in this subroutine

  if (.not. associated(cs)) return

  deallocate(cs%N2)
  deallocate(cs%kd_conv)
  deallocate(cs%kv_conv)
  deallocate(cs)

end subroutine cvmix_conv_end

end module mom_cvmix_conv