BFB_surface_forcing.F90

!> Surface forcing for the boundary-forced-basin (BFB) configuration
module bfb_surface_forcing
 
! This file is part of MOM6. See LICENSE.md for the license.
 
use mom_diag_mediator, only : post_data, query_averaging_enabled
use mom_diag_mediator, only : register_diag_field, diag_ctrl
use mom_domains, only : pass_var, pass_vector, agrid
use mom_error_handler, only : mom_error, fatal, warning, is_root_pe
use mom_file_parser, only : get_param, param_file_type, log_version
use mom_forcing_type, only : forcing, allocate_forcing_type
use mom_grid, only : ocean_grid_type
use mom_io, only : file_exists, read_data
use mom_safe_alloc, only : safe_alloc_ptr
use mom_time_manager, only : time_type, operator(+), operator(/)
use mom_tracer_flow_control, only : call_tracer_set_forcing
use mom_tracer_flow_control, only : tracer_flow_control_cs
use mom_unit_scaling, only : unit_scale_type
use mom_variables, only : surface
 
implicit none ; private
 
public bfb_buoyancy_forcing, bfb_surface_forcing_init
 
!> Control structure for BFB_surface_forcing
type, public :: bfb_surface_forcing_cs ; private
 
  logical :: use_temperature !< If true, temperature and salinity are used as state variables.
  logical :: restorebuoy     !< If true, use restoring surface buoyancy forcing.
  real :: rho0               !< The density used in the Boussinesq approximation [R ~> kg m-3].
  real :: g_earth            !< The gravitational acceleration [L2 Z-1 T-2 ~> m s-2]
  real :: flux_const         !< The restoring rate at the surface [Z T-1 ~> m s-1].
  real :: gust_const         !< A constant unresolved background gustiness
                             !! that contributes to ustar [Pa].
  real :: sst_s              !< SST at the southern edge of the linear forcing ramp [degC]
  real :: sst_n              !< SST at the northern edge of the linear forcing ramp [degC]
  real :: lfrslat            !< Southern latitude where the linear forcing ramp begins [degLat]
  real :: lfrnlat            !< Northern latitude where the linear forcing ramp ends [degLat]
  real :: drho_dt            !< Rate of change of density with temperature [R degC-1 ~> kg m-3 degC-1].
                             !!   Note that temperature is being used as a dummy variable here.
                             !! All temperatures are converted into density.
 
  type(diag_ctrl), pointer :: diag => null() !< A structure that is used to
                             !! regulate the timing of diagnostic output.
end type bfb_surface_forcing_cs
 
contains
 
!> Bouyancy forcing for the boundary-forced-basin (BFB) configuration
subroutine bfb_buoyancy_forcing(sfc_state, fluxes, day, dt, G, US, CS)
  type(surface),                intent(inout) :: sfc_state  !< A structure containing fields that
                                                      !! describe the surface state of the ocean.
  type(forcing),                intent(inout) :: fluxes !< A structure containing pointers to any
                                                      !! possible forcing fields. Unused fields
                                                      !! have NULL ptrs.
  type(time_type),              intent(in)    :: day  !< Time of the fluxes.
  real,                         intent(in)    :: dt   !< The amount of time over which
                                                      !! the fluxes apply [s]
  type(ocean_grid_type),        intent(in)    :: g    !< The ocean's grid structure
  type(unit_scale_type),        intent(in)    :: us   !< A dimensional unit scaling type
  type(bfb_surface_forcing_cs), pointer       :: cs   !< A pointer to the control structure
                                                      !! returned by a previous call to
                                                      !! BFB_surface_forcing_init.
  ! Local variables
  real :: temp_restore   ! The temperature that is being restored toward [degC].
  real :: salin_restore  ! The salinity that is being restored toward [ppt].
  real :: density_restore  ! The potential density that is being restored
                         ! toward [R ~> kg m-3].
  real :: rhoxcp           ! Reference density times heat capacity times unit scaling
                           ! factors [Q R degC-1 ~> J m-3 degC-1]
  real :: buoy_rest_const  ! A constant relating density anomalies to the
                           ! restoring buoyancy flux [L2 T-3 R-1 ~> m5 s-3 kg-1].
  integer :: i, j, is, ie, js, je
  integer :: isd, ied, jsd, jed
 
  is = g%isc ; ie = g%iec ; js = g%jsc ; je = g%jec
  isd = g%isd ; ied = g%ied ; jsd = g%jsd ; jed = g%jed
 
  ! Allocate and zero out the forcing arrays, as necessary.  This portion is
  ! usually not changed.
  if (cs%use_temperature) then
    call safe_alloc_ptr(fluxes%evap, isd, ied, jsd, jed)
    call safe_alloc_ptr(fluxes%lprec, isd, ied, jsd, jed)
    call safe_alloc_ptr(fluxes%fprec, isd, ied, jsd, jed)
    call safe_alloc_ptr(fluxes%lrunoff, isd, ied, jsd, jed)
    call safe_alloc_ptr(fluxes%frunoff, isd, ied, jsd, jed)
    call safe_alloc_ptr(fluxes%vprec, isd, ied, jsd, jed)
 
    call safe_alloc_ptr(fluxes%sw, isd, ied, jsd, jed)
    call safe_alloc_ptr(fluxes%lw, isd, ied, jsd, jed)
    call safe_alloc_ptr(fluxes%latent, isd, ied, jsd, jed)
    call safe_alloc_ptr(fluxes%sens, isd, ied, jsd, jed)
  else ! This is the buoyancy only mode.
    call safe_alloc_ptr(fluxes%buoy, isd, ied, jsd, jed)
  endif
 
  if ( cs%use_temperature ) then
    ! Set whichever fluxes are to be used here.  Any fluxes that
    ! are always zero do not need to be changed here.
    do j=js,je ; do i=is,ie
      ! Fluxes of fresh water through the surface are in units of [R Z T-1 ~> kg m-2 s-1]
      ! and are positive downward - i.e. evaporation should be negative.
      fluxes%evap(i,j) = -0.0 * g%mask2dT(i,j)
      fluxes%lprec(i,j) = 0.0 * g%mask2dT(i,j)
 
      ! vprec will be set later, if it is needed for salinity restoring.
      fluxes%vprec(i,j) = 0.0
 
      ! Heat fluxes are in units of [Q R Z T-1 ~> W m-2] and are positive into the ocean.
      fluxes%lw(i,j) = 0.0 * g%mask2dT(i,j)
      fluxes%latent(i,j) = 0.0 * g%mask2dT(i,j)
      fluxes%sens(i,j) = 0.0 * g%mask2dT(i,j)
      fluxes%sw(i,j) = 0.0 * g%mask2dT(i,j)
    enddo ; enddo
  else ! This is the buoyancy only mode.
    do j=js,je ; do i=is,ie
      !   fluxes%buoy is the buoyancy flux into the ocean [L2 T-3 ~> m2 s-3].  A positive
      ! buoyancy flux is of the same sign as heating the ocean.
      fluxes%buoy(i,j) = 0.0 * g%mask2dT(i,j)
    enddo ; enddo
  endif
 
  if (cs%restorebuoy) then
    if (cs%use_temperature) then
      call safe_alloc_ptr(fluxes%heat_added, isd, ied, jsd, jed)
      !   When modifying the code, comment out this error message.  It is here
      ! so that the original (unmodified) version is not accidentally used.
      call mom_error(fatal, "User_buoyancy_surface_forcing: " // &
        "Temperature and salinity restoring used without modification." )
 
      rhoxcp = cs%Rho0 * fluxes%C_p
      do j=js,je ; do i=is,ie
        !   Set Temp_restore and Salin_restore to the temperature (in degC) and
        ! salinity (in ppt) that are being restored toward.
        temp_restore = 0.0
        salin_restore = 0.0
 
        fluxes%heat_added(i,j) = (g%mask2dT(i,j) * (rhoxcp * cs%Flux_const)) * &
            (temp_restore - sfc_state%SST(i,j))
        fluxes%vprec(i,j) = - (g%mask2dT(i,j) * (cs%Rho0*cs%Flux_const)) * &
            ((salin_restore - sfc_state%SSS(i,j)) / (0.5 * (salin_restore + sfc_state%SSS(i,j))))
      enddo ; enddo
    else
      !   When modifying the code, comment out this error message.  It is here
      ! so that the original (unmodified) version is not accidentally used.
      ! call MOM_error(FATAL, "User_buoyancy_surface_forcing: " // &
      !   "Buoyancy restoring used without modification." )
 
      ! The -1 is because density has the opposite sign to buoyancy.
      buoy_rest_const = -1.0 * (cs%G_Earth * cs%Flux_const) / cs%Rho0
      temp_restore = 0.0
      do j=js,je ; do i=is,ie
       !   Set density_restore to an expression for the surface potential
       ! density [R ~> kg m-3] that is being restored toward.
        if (g%geoLatT(i,j) < cs%lfrslat) then
            temp_restore = cs%SST_s
        elseif (g%geoLatT(i,j) > cs%lfrnlat) then
            temp_restore = cs%SST_n
        else
            temp_restore = (cs%SST_s - cs%SST_n)/(cs%lfrslat - cs%lfrnlat) * &
                    (g%geoLatT(i,j) - cs%lfrslat) + cs%SST_s
        endif
 
        density_restore = temp_restore*cs%drho_dt + cs%Rho0
 
        fluxes%buoy(i,j) = g%mask2dT(i,j) * buoy_rest_const * &
                          (density_restore - sfc_state%sfc_density(i,j))
      enddo ; enddo
    endif
  endif                                             ! end RESTOREBUOY
 
end subroutine bfb_buoyancy_forcing
 
!> Initialization for forcing the boundary-forced-basin (BFB) configuration
subroutine bfb_surface_forcing_init(Time, G, US, param_file, diag, CS)
  type(time_type),              intent(in) :: time !< The current model time.
  type(ocean_grid_type),        intent(in) :: g    !< The ocean's grid structure
  type(unit_scale_type),        intent(in) :: us   !< A dimensional unit scaling type
  type(param_file_type),        intent(in) :: param_file !< A structure to parse for run-time parameters
  type(diag_ctrl), target,      intent(in) :: diag !< A structure that is used to
                                                   !! regulate diagnostic output.
  type(bfb_surface_forcing_cs), pointer    :: cs   !< A pointer to the control structure for this module
! This include declares and sets the variable "version".
#include "version_variable.h"
  character(len=40)  :: mdl = "BFB_surface_forcing" ! This module's name.
 
  if (associated(cs)) then
    call mom_error(warning, "BFB_surface_forcing_init called with an associated "// &
                             "control structure.")
    return
  endif
  allocate(cs)
  cs%diag => diag
 
  ! Read all relevant parameters and write them to the model log.
  call log_version(param_file, mdl, version, "")
  call get_param(param_file, mdl, "ENABLE_THERMODYNAMICS", cs%use_temperature, &
                 "If true, Temperature and salinity are used as state variables.", default=.true.)
 
  call get_param(param_file, mdl, "G_EARTH", cs%G_Earth, &
                 "The gravitational acceleration of the Earth.", &
                 units="m s-2", default = 9.80, scale=us%m_to_L**2*us%Z_to_m*us%T_to_s**2)
  call get_param(param_file, mdl, "RHO_0", cs%Rho0, &
                 "The mean ocean density used with BOUSSINESQ true to "//&
                 "calculate accelerations and the mass for conservation "//&
                 "properties, or with BOUSSINSEQ false to convert some "//&
                 "parameters from vertical units of m to kg m-2.", &
                 units="kg m-3", default=1035.0, scale=us%kg_m3_to_R)
  call get_param(param_file, mdl, "LFR_SLAT", cs%lfrslat, &
                 "Southern latitude where the linear forcing ramp begins.", &
                 units="degrees", default=20.0)
  call get_param(param_file, mdl, "LFR_NLAT", cs%lfrnlat, &
                 "Northern latitude where the linear forcing ramp ends.", &
                 units="degrees", default=40.0)
  call get_param(param_file, mdl, "SST_S", cs%SST_s, &
                 "SST at the southern edge of the linear forcing ramp.", &
                 units="C", default=20.0)
  call get_param(param_file, mdl, "SST_N", cs%SST_n, &
                 "SST at the northern edge of the linear forcing ramp.", &
                 units="C", default=10.0)
  call get_param(param_file, mdl, "DRHO_DT", cs%drho_dt, &
                 "The rate of change of density with temperature.", &
                 units="kg m-3 K-1", default=-0.2, scale=us%kg_m3_to_R)
  call get_param(param_file, mdl, "GUST_CONST", cs%gust_const, &
                 "The background gustiness in the winds.", units="Pa", default=0.0)
 
  call get_param(param_file, mdl, "RESTOREBUOY", cs%restorebuoy, &
                 "If true, the buoyancy fluxes drive the model back "//&
                 "toward some specified surface state with a rate "//&
                 "given by FLUXCONST.", default= .false.)
  if (cs%restorebuoy) then
    call get_param(param_file, mdl, "FLUXCONST", cs%Flux_const, &
                 "The constant that relates the restoring surface fluxes to the relative "//&
                 "surface anomalies (akin to a piston velocity).  Note the non-MKS units.", &
                 default=0.0, units="m day-1", scale=us%m_to_Z*us%T_to_s)
    ! Convert CS%Flux_const from m day-1 to m s-1.
    cs%Flux_const = cs%Flux_const / 86400.0
  endif
 
end subroutine bfb_surface_forcing_init
 
end module bfb_surface_forcing