dyed_obcs_initialization.F90

!> Dyed open boundary conditions
module dyed_obcs_initialization

! This file is part of MOM6. See LICENSE.md for the license.

use mom_dyn_horgrid,     only : dyn_horgrid_type
use mom_error_handler,   only : mom_mesg, mom_error, fatal, warning, is_root_pe
use mom_file_parser,     only : get_param, log_version, param_file_type
use mom_get_input,       only : directories
use mom_grid,            only : ocean_grid_type
use mom_open_boundary,   only : ocean_obc_type, obc_none, obc_simple
use mom_open_boundary,   only : obc_segment_type, register_segment_tracer
use mom_tracer_registry, only : tracer_registry_type, tracer_name_lookup
use mom_tracer_registry, only : tracer_type
use mom_variables,       only : thermo_var_ptrs
use mom_verticalgrid,    only : verticalgrid_type

implicit none ; private

#include <MOM_memory.h>

public dyed_obcs_set_obc_data

integer :: ntr = 0 !< Number of dye tracers
                   !! \todo This is a module variable. Move this variable into the control structure.

contains

!> This subroutine sets the dye properties at open boundary conditions.
subroutine dyed_obcs_set_obc_data(OBC, G, GV, param_file, tr_Reg)
  type(ocean_obc_type),       pointer    :: obc !< This open boundary condition type specifies
                                                !! whether, where, and what open boundary
                                                !! conditions are used.
  type(ocean_grid_type),      intent(in) :: g   !< The ocean's grid structure.
  type(verticalgrid_type),    intent(in) :: gv  !< The ocean's vertical grid structure.
  type(param_file_type),      intent(in) :: param_file !< A structure indicating the open file
                                                !! to parse for model parameter values.
  type(tracer_registry_type), pointer    :: tr_reg !< Tracer registry.
  ! Local variables
  character(len=40)  :: mdl = "dyed_obcs_set_OBC_data" ! This subroutine's name.
  character(len=80)  :: name, longname
  integer :: i, j, k, itt, is, ie, js, je, isd, ied, jsd, jed, m, n, nz
  integer :: isdb, iedb, jsdb, jedb
  real :: dye
  type(obc_segment_type), pointer :: segment => null()
  type(tracer_type), pointer      :: tr_ptr => null()

  is = g%isc ; ie = g%iec ; js = g%jsc ; je = g%jec ; nz = g%ke
  isd = g%isd ; ied = g%ied ; jsd = g%jsd ; jed = g%jed
  isdb = g%IsdB ; iedb = g%IedB ; jsdb = g%JsdB ; jedb = g%JedB

  if (.not.associated(obc)) return

  call get_param(param_file, mdl, "NUM_DYE_TRACERS", ntr, &
                 "The number of dye tracers in this run. Each tracer "//&
                 "should have a separate boundary segment.", default=0,   &
                 do_not_log=.true.)

  if (obc%number_of_segments < ntr) then
    call mom_error(warning, "Error in dyed_obc segment setup")
    return   !!! Need a better error message here
  endif

! ! Set the inflow values of the dyes, one per segment.
! ! We know the order: north, south, east, west
  do m=1,ntr
    write(name,'("dye_",I2.2)') m
    write(longname,'("Concentration of dyed_obc Tracer ",I2.2, " on segment ",I2.2)') m, m
    call tracer_name_lookup(tr_reg, tr_ptr, name)

    do n=1,obc%number_of_segments
      if (n == m) then
        dye = 1.0
      else
        dye = 0.0
      endif
      call register_segment_tracer(tr_ptr, param_file, gv, &
                                   obc%segment(n), obc_scalar=dye)
    enddo
  enddo

end subroutine dyed_obcs_set_obc_data

!> \namespace dyed_obcs_initialization
!!
!! Setting dyes, one for painting the inflow on each side.
end module dyed_obcs_initialization